macro prt_dndy_plot_feb02 sys=2 prt=pim ver=final
vec/del *
hi/del *

vec/cre mt_m0(40) r
do i=1,40
        mt-mo = $eval(([i]*0.025)-0.0125)
        vec/in mt_m0([i]) [mt-mo]
enddo

* Read the Data files into vectors
exec par_prt_dndy_feb02 [sys] [prt] [ver]

* Define the number of rapidity bins
if ([sys].eq.2) then
  bins=9
elseif ([sys].eq.4) then
  bins=12
elseif ([sys].eq.6) then
  bins=14
elseif ([sys].eq.8) then
  bins=15
endif

* Scale by orders of Magnitude
do j=1,[bins]
    vec/op/vscale amp_[prt][sys]_f[j] $eval(1e[j]) amp_[prt][sys]_f[j]
    vec/op/vscale err_[prt][sys]_f[j] $eval(1e[j]) err_[prt][sys]_f[j]
enddo

do j=1,[bins]
    vec/op/vscale amp_[prt][sys]_b[j] $eval(1e-[j]) amp_[prt][sys]_b[j]
    vec/op/vscale err_[prt][sys]_b[j] $eval(1e-[j]) err_[prt][sys]_b[j]
enddo
  
* Create the Histograms
1d 1000 ''//[sys]//'gev [prt] at y0' 40 0.0 1.0

do i=1,[bins]
  1d 100[i] ''//[sys]//'gev [prt] at b'//[i]//'' 40 0.0 1.0
  1d 200[i] ''//[sys]//'gev [prt] at f'//[i]//'' 40 0.0 1.0
enddo

* Load vectors into Histograms
hi/put_vec/con 1000 amp_[prt][sys]_y0
hi/put_vec/err 1000 err_[prt][sys]_y0

do i=1,[bins]
 hi/put_vec/con 100[i] amp_[prt][sys]_b[i]
 hi/put_vec/err 100[i] err_[prt][sys]_b[i]

 hi/put_vec/con 200[i] amp_[prt][sys]_f[i]
 hi/put_vec/err 200[i] err_[prt][sys]_f[i]
enddo

set errx 0.0001

open_pic

title ''//[sys]//' AGeV '//[prt]//' Spectra'
opt logy

set mtyp 20
igset pmci 1
null 0 1 1e-12 1e18
hi/plot 1000 ps

do i=1,[bins],1
 igset pmci 2
 hi/plot 100[i] ps
 igset pmci 3
 hi/plot 200[i] ps
enddo
igset pmci 1

exec setup 

close_pic

return


macro setup 

zone 1 1     
*
*
set tang 0   
set ltyp 1

selnt 1

set txal 20
igset chhe 0.6
set tang 0
itx 10.0 0.5 'm?t!-m?0! (GeV/c^2!)'
set tang 90
itx 0.8 10 '1/(2[p]m?t!)d^2!N/dm?t!dy ((GeV/c^2!)^-2!)'
set tang 0

return

macro par_prt_dndy_feb02 sys=2 prt=pim ver=final

dir='../specmt'

if ([sys].eq.2) then
  bins=9
elseif ([sys].eq.4) then
  bins=12
elseif ([sys].eq.6) then
  bins=14
elseif ([sys].eq.8) then
  bins=15
endif

vec/cre foo(3,40) r
vec/read foo _
[dir]/[sys]gev_[prt]_y0_[ver].dat
vec/cre amp_[prt][sys]_y0(40) r
vec/cre err_[prt][sys]_y0(40) r
vec/copy foo(2,1:40) amp_[prt][sys]_y0(1:40)
vec/copy foo(3,1:40) err_[prt][sys]_y0(1:40)

do i=1,[bins]
   vec/cre foo(3,40) r
   vec/read foo _   
[dir]/[sys]gev_[prt]_b[i]_[ver].dat
   vec/cre amp_[prt][sys]_b[i](40) r
   vec/cre err_[prt][sys]_b[i](40) r
   vec/copy foo(2,1:40) amp_[prt][sys]_b[i](1:40)
   vec/copy foo(3,1:40) err_[prt][sys]_b[i](1:40)

   vec/cre foo(3,40) r
   vec/read foo _   
[dir]/[sys]gev_[prt]_f[i]_[ver].dat
   vec/cre amp_[prt][sys]_f[i](40) r
   vec/cre err_[prt][sys]_f[i](40) r
   vec/copy foo(2,1:40) amp_[prt][sys]_f[i](1:40)
   vec/copy foo(3,1:40) err_[prt][sys]_f[i](1:40)
enddo
   
return